# filebrowser-ng developer tasks

dev-root := '.dev/root'
dev-db := '.dev/db.sqlite'

default: dev

# Create the dev root folder.
dev-data:
    mkdir -p {{dev-root}}

# Backend (dev): serves the frontend from Trunk's output directory.
# Frontend dev server:    just dev-web   (port 8080)
# Backend dev server:     just dev-server (port 8081, /api proxied by Trunk)
dev: dev-data dev-server

dev-server:
    cargo run -p server -- --root {{dev-root}} --db {{dev-db}} --port 8081

dev-web:
    cd web && trunk serve --proxy-rewrite /api --proxy-backend http://127.0.0.1:8081

# Production single binary (frontend embedded).
build:
    cd web && trunk build --release
    rm -rf server/dist
    cp -r web/dist server/dist
    cargo build --release -p server --features embedded

# Run the production binary against the dev folders.
run: build
    ./target/release/filebrowser-ng --root {{dev-root}} --db {{dev-db}}

# Remove the dev database (factory reset of users/shares/settings).
reset-db:
    rm -f {{dev-db}} {{dev-db}}-wal {{dev-db}}-shm